// Возвращает отформатированный текст плана запроса, выровненный по столбцам в части цифр.
//
// Параметры:
//  ТекстПланаЗапроса  - Строка, "сырой" текст плана запроса
//
// Возвращаемое значение:
//   Строка, результат форматирования
//
Функция ФорматироватьПланЗапроса(ТекстПланаЗапроса)

    Если ПустаяСтрока(ТекстПланаЗапроса) Тогда Возврат "" КонецЕсли;
    
    ШаблонМакет =
    "#Область Трасса
    | #Поле Показатель1
    |  #Выравнивание Право
    | #Поле Показатель2
    |  #Выравнивание Право
    | #Поле Показатель3
    |  #Выравнивание Право
    | #Поле Показатель4
    |  #Выравнивание Лево
    | #Поле Показатель5
    |  #Выравнивание Лево
    | #Поле Показатель6
    |  #Выравнивание Право
    | #Поле Показатель7
    |  #Выравнивание Лево
    | #Поле Показатель8
    |  #Выравнивание Право
    | #Поле Расшифровка
    |  #Выравнивание Лево
    |[Показатель1][Показатель2][Показатель3][Показатель4][Показатель5][Показатель6][Показатель7][Показатель8][Расшифровка]#Поля Показатель1 Показатель2 Показатель3 Показатель4 Показатель5 Показатель6 Показатель7 Показатель8 Расшифровка
    |#КонецОбласти";
    
    Размерность = Новый Структура;
    ТаблицаТрасса = Новый ТаблицаЗначений;
    
    Колонки = Новый Массив;
    Для пц = 1 По 8 Цикл Колонки.Добавить("Показатель" + пц); КонецЦикла;
    Колонки.Добавить("Расшифровка");
    
    Для каждого Колонка Из Колонки Цикл
        ТаблицаТрасса.Колонки.Добавить(Колонка, Новый ОписаниеТипов("Строка"));
        Размерность.Вставить(Колонка, 0);
    КонецЦикла;
    
    Для пц = 1 По СтрЧислоСтрок(ТекстПланаЗапроса) Цикл
        ЭлементТрассы = СтрЗаменить(СтрПолучитьСтроку(ТекстПланаЗапроса, пц), ",", Символы.ПС);
        НоваяСтрока = ТаблицаТрасса.Добавить();
        Для пц1 = 1 По 8 Цикл
            НоваяСтрока["Показатель" + пц1] = СтрПолучитьСтроку(ЭлементТрассы, пц1) + ",";
        КонецЦикла;
        Расшифровка = "";
        Для пц1 = 9 По СтрЧислоСтрок(ЭлементТрассы) Цикл
            Расшифровка = Расшифровка + "," + СтрПолучитьСтроку(ЭлементТрассы, пц1);
        КонецЦикла;
        НоваяСтрока.Расшифровка = Сред(Расшифровка, 2);
        Для каждого Колонка Из Колонки Цикл
            Размерность[Колонка] = Макс(Размерность[Колонка], СтрДлина(НоваяСтрока[Колонка]));
        КонецЦикла;
    КонецЦикла;
    
    Забивка = "";
    Для пц = 1 По Размерность.Расшифровка Цикл Забивка = Забивка + " "; КонецЦикла;
    
    МакетТекст = ШаблонМакет;
    Для каждого Колонка Из Колонки Цикл
        ЧтоИщем = "[" + Колонка + "]";
        ЧтоМеняем = "[" + Лев(Забивка, Размерность[Колонка] - 2) + "]";
        МакетТекст = СтрЗаменить(МакетТекст, ЧтоИщем, ЧтоМеняем);
    КонецЦикла;
    
    Макет = Новый ТекстовыйДокумент;
    Макет.УстановитьТекст(МакетТекст);
    
    Документ = Новый ТекстовыйДокумент;
    Для каждого Строка Из ТаблицаТрасса Цикл
        Область = Макет.ПолучитьОбласть("Трасса");
        ЗаполнитьЗначенияСвойств(Область.Параметры, Строка);
        Документ.Вывести(Область);
    КонецЦикла;
    
    Возврат Документ.ПолучитьТекст();

КонецФункции // ФорматироватьПланЗапроса()