Функция ТекущиеСвойстваПользователей(МассивПользователей) Экспорт
    
    Запрос = Новый Запрос;
    
    Запрос.УстановитьПараметр("ПустойИдентификатор",
        Новый УникальныйИдентификатор("00000000-0000-0000-0000-000000000000"));
    
    Если МассивПользователей = Неопределено Тогда
        Запрос.Текст =
        "ВЫБРАТЬ
        |    Пользователи.Ссылка КАК Пользователь,
        |    Пользователи.ИдентификаторПользователяИБ
        |ПОМЕСТИТЬ ПроверяемыеПользователи
        |ИЗ
        |    Справочник.Пользователи КАК Пользователи
        |ГДЕ
        |    Пользователи.Служебный = ЛОЖЬ
        |    И Пользователи.ИдентификаторПользователяИБ <> &ПустойИдентификатор
        |
        |ОБЪЕДИНИТЬ ВСЕ
        |
        |ВЫБРАТЬ
        |    ВнешниеПользователи.Ссылка,
        |    ВнешниеПользователи.ИдентификаторПользователяИБ
        |ИЗ
        |    Справочник.ВнешниеПользователи КАК ВнешниеПользователи
        |ГДЕ
        |    ВнешниеПользователи.ИдентификаторПользователяИБ <> &ПустойИдентификатор";
        
    ИначеЕсли ТипЗнч(МассивПользователей) = Тип("Тип") Тогда
        Если Метаданные.НайтиПоТипу(МассивПользователей) = Метаданные.Справочники.ВнешниеПользователи Тогда
            Запрос.Текст =
            "ВЫБРАТЬ
            |    ВнешниеПользователи.Ссылка КАК Пользователь,
            |    ВнешниеПользователи.ИдентификаторПользователяИБ
            |ПОМЕСТИТЬ ПроверяемыеПользователи
            |ИЗ
            |    Справочник.ВнешниеПользователи КАК ВнешниеПользователи
            |ГДЕ
            |    ВнешниеПользователи.ИдентификаторПользователяИБ <> &ПустойИдентификатор";
        Иначе
            Запрос.Текст =
            "ВЫБРАТЬ
            |    Пользователи.Ссылка КАК Пользователь,
            |    Пользователи.ИдентификаторПользователяИБ
            |ПОМЕСТИТЬ ПроверяемыеПользователи
            |ИЗ
            |    Справочник.Пользователи КАК Пользователи
            |ГДЕ
            |    Пользователи.Служебный = ЛОЖЬ
            |    И Пользователи.ИдентификаторПользователяИБ <> &ПустойИдентификатор";
        КонецЕсли;
    Иначе
        ИсходныеПользователи = Новый ТаблицаЗначений;
        ИсходныеПользователи.Колонки.Добавить("Пользователь", Новый ОписаниеТипов(
            "СправочникСсылка.Пользователи, СправочникСсылка.ВнешниеПользователи"));
        
        Для каждого Пользователь Из МассивПользователей Цикл
            ИсходныеПользователи.Добавить().Пользователь = Пользователь;
        КонецЦикла;
        
        Запрос.УстановитьПараметр("ИсходныеПользователи", ИсходныеПользователи);
        Запрос.Текст =
        "ВЫБРАТЬ РАЗЛИЧНЫЕ
        |    ИсходныеПользователи.Пользователь
        |ПОМЕСТИТЬ ИсходныеПользователи
        |ИЗ
        |    &ИсходныеПользователи КАК ИсходныеПользователи
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ
        |    Пользователи.Ссылка КАК Пользователь,
        |    Пользователи.ИдентификаторПользователяИБ
        |ПОМЕСТИТЬ ПроверяемыеПользователи
        |ИЗ
        |    Справочник.Пользователи КАК Пользователи
        |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ИсходныеПользователи КАК ИсходныеПользователи
        |        ПО Пользователи.Ссылка = ИсходныеПользователи.Пользователь
        |            И (Пользователи.Служебный = ЛОЖЬ)
        |            И (Пользователи.ИдентификаторПользователяИБ <> &ПустойИдентификатор)
        |
        |ОБЪЕДИНИТЬ ВСЕ
        |
        |ВЫБРАТЬ
        |    ВнешниеПользователи.Ссылка,
        |    ВнешниеПользователи.ИдентификаторПользователяИБ
        |ИЗ
        |    Справочник.ВнешниеПользователи КАК ВнешниеПользователи
        |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ИсходныеПользователи КАК ИсходныеПользователи
        |        ПО ВнешниеПользователи.Ссылка = ИсходныеПользователи.Пользователь
        |            И (ВнешниеПользователи.ИдентификаторПользователяИБ <> &ПустойИдентификатор)";
    КонецЕсли;
    
    Запрос.Текст = Запрос.Текст + "
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |" +
    "ВЫБРАТЬ
    |    ПользователиВКонтейнерах.Пользователь КАК Ссылка,
    |    ПользователиВКонтейнерах.Пользователь.ИдентификаторПользователяИБ
    |ИЗ
    |    РегистрСведений.ПолномочияПользователей КАК ПолномочияПользователей
    |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ПользователиВКонтейнерах КАК ПользователиВКонтейнерах
    |        ПО (ПолномочияПользователей.Полномочия = ЗНАЧЕНИЕ(Справочник.ПрофилиГруппДоступа.Администратор))
    |            И ПолномочияПользователей.Владелец = ПользователиВКонтейнерах.Контейнер
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |    ПроверяемыеПользователи.Пользователь,
    |    ПроверяемыеПользователи.ИдентификаторПользователяИБ
    |ИЗ
    |    ПроверяемыеПользователи КАК ПроверяемыеПользователи
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ РАЗЛИЧНЫЕ
    |    ПроверяемыеПользователи.Пользователь КАК Пользователь,
    |    ПолномочияПользователей.Полномочия КАК Профиль
    |ПОМЕСТИТЬ ПрофилиПользователей
    |ИЗ
    |    ПроверяемыеПользователи КАК ПроверяемыеПользователи
    |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ПользователиВКонтейнерах КАК ПользователиВКонтейнерах
    |            ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ПолномочияПользователей КАК ПолномочияПользователей
    |            ПО ПользователиВКонтейнерах.Контейнер = ПолномочияПользователей.Владелец
    |        ПО ПроверяемыеПользователи.Пользователь = ПользователиВКонтейнерах.Пользователь
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ РАЗЛИЧНЫЕ
    |    ПрофилиПользователей.Пользователь,
    |    Роли.Роль.Имя КАК Роль
    |ИЗ
    |    ПрофилиПользователей КАК ПрофилиПользователей
    |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.ПрофилиГруппДоступа.Роли КАК Роли
    |        ПО (Роли.Ссылка = ПрофилиПользователей.Профиль)
    |            И (НЕ Роли.Ссылка.ПометкаУдаления)";
    
    Если ПолучитьФункциональнуюОпцию("ИспользоватьВнешнихПользователей") Тогда
        Запрос.Текст = СтрЗаменить(Запрос.Текст, "&ИсключитьВнешнихПользователей", "Истина");
    Иначе
        Запрос.Текст = СтрЗаменить(Запрос.Текст, "&ИсключитьВнешнихПользователей",
            "ТИПЗНАЧЕНИЯ(ПроверяемыеПользователи.Пользователь) = ТИП(Справочник.Пользователи)");
    КонецЕсли;
    
    РезультатыЗапросов = Запрос.ВыполнитьПакет();
    ПоследнийРезультат = РезультатыЗапросов.Количество()-1;
    Итог = Новый Структура;
    
    Итог.Вставить("Администраторы", Новый Соответствие);
    
    Для каждого Строка Из РезультатыЗапросов[ПоследнийРезультат-3].Выгрузить() Цикл
        Итог.Администраторы.Вставить(Строка.Ссылка, Истина);
    КонецЦикла;
    
    Итог.Вставить("ИдентификаторыПользователейИБ", РезультатыЗапросов[ПоследнийРезультат-2].Выгрузить());
    Итог.ИдентификаторыПользователейИБ.Индексы.Добавить("Пользователь");
    
    Итог.Вставить("РолиПользователей", РезультатыЗапросов[ПоследнийРезультат].Выгрузить());
    Итог.РолиПользователей.Индексы.Добавить("Пользователь");
    
    Возврат Итог;
    
КонецФункции